*master syntax file for National Civic Engagement Survey II, Replication Survey Fall 2002.

GET FILE='C:\Replication Fall 2002.sav'.

weight by weight.
recode age (18 thru 25=25)(26 thru 37=37)(38 thru 56=56)(57 thru 97=97)(else=99) into agegroup.
missing values agegroup (99).
value labels agegroup 25 '18-25' 37 '26-37' 56 '38-56' 97 '57+'.
var labels agegroup 'Age cohorts'.

recode gpa (1=1)(else=0) into anygroup.
recode gxa (1,4=1)(else=0) into active.
recode gxb (1=1)(else=0) into polgroup.
var labels anygroup 'Member of at least one group' /active 'Active member of at least one group'
  /polgroup 'Member of group that takes stands'.

compute volunt=0.
if v1a=1 volunt=1.
if v1b=1 volunt=1.
var labels volunt 'Volunteered in last 12 months (any type)'.

recode vp3 (1=1)(else=0) into voting.

recode int4 (1=1)(else=0) into commprob.
compute persuade=0.
if house=1 and pp1 le 2 persuade=1.
if house=2 and pp1=1 persuade=1.

compute button=0.
if house=1 and pp2 le 2 button=1.
if house=2 and pp2=1 button=1.

recode pp6 (1=1)(else=0) into monwork.
recode pp7a (3=1)(else=0) into contoff.
recode pp7b (3=1)(else=0) into contmed.
recode pp7c (3=1)(else=0) into talkshow.
recode pp7d (3=1)(else=0) into protest.
recode pp7e (3=1)(else=0) into epet.
recode pp7f (3=1)(else=0) into wpet.
recode pp7g (3=1)(else=0) into boycott.
recode pp7h (3=1)(else=0) into buycott.
recode pp7i (3=1)(else=0) into runwalk.
recode pp7j (3=1)(else=0) into raisemon.
recode pp7k (3=1)(else=0) into canvass.

recode mi7a (8,9=0)(else=copy) into newsp.
recode mi7b (8,9=0)(else=copy) into newsmag.
recode mi7c (8,9=0)(else=copy) into tvnews.
recode mi7d (8,9=0)(else=copy) into radionew.
recode mi7e (8,9=0)(else=copy) into netnews.

compute mediause=sum(newsp,newsmag,tvnews,radionew,netnews).

compute raisemoo=0.
if (runwalk=1) or (raisemon=1) raisemoo=1.

compute npvolreg=0.
if any(1,v3aRELIG,v3aENVIR,v3aCIVIC,v3aYOUTH,v3aOTHER) npvolreg=1.
if any(1,v3bRELIG,v3bENVIR,v3bCIVIC,v3bYOUTH,v3bOTHER) npvolreg=1.
var labels npvolreg 'Regular volunteer for nonpolitical organization (last 12 months)'.

compute vpolreg=0.
if v3aPOLIT=1 vpolreg=1.
if v3bPOLIT=1 vpolreg=1.
var labels vpolreg 'Vol regularly for cand or pol group (last 12 months)'.

compute polvol=0.
if v2ab=1 polvol=1.
if v2bb=1 polvol=1.
var labels polvol 'Volunteered for cand or pol group (last 12 months)'.

* creating the typology.
compute civideal=sum(npvolreg,commprob,active,raisemoo).
var labels civideal 'Four item civic engagement index for ideal citizen'.
compute polideal=sum(button, monwork, persuade,polvol,voting).
var labels polideal 'Five item political engagement index'.
value labels polideal civideal 0 '0' 1 '1' 2 '2' 3 '3' 4 '4' 5 '5'.
recode polideal (0,1=0)(2,3,4,5=1) into polid2.
recode civideal (0,1=0)(2,3,4=1) into civid2.
var labels polid2 'Score on electoral ideal index'.
var labels civid2 'Score on civic ideal index'.
value labels polid2 civid2  0 'Less than 2' 1 '2 or higher'.

*** computing typology *****.
compute typolid1=0.
if polid2=1 and civid2=0 typolid1=1.
if polid2=0 and civid2=1 typolid1=2.
if polid2=1 and civid2=1 typolid1=3.
var labels typolid1 'Typology of Engagement'.
value labels typolid1 0 'Disengaged' 1 'Electoral' 2 'Civic specialist' 3 'Dual activist'.
***********************************************************************************************************.

var labels contoff 'Contacted official (last 12 months)'
  /commprob 'Worked to solve community problem (last 12 months)'
  /persuade 'Tried to persuade others in election'
  /button 'Displayed campaign button or sign'
  /monwork 'Worked for or donated money to cand or party (last 12 months)'
  /contmed 'Contacted news media (last 12 months)'
  /talkshow 'Called a talk show (last 12 months)'
  /protest 'Protested (last 12 months)'
  /epet 'Signed e-mail petition (last 12 months)'
  /wpet 'Signed paper petition (last 12 months)'
  /boycott 'Boycotted (last 12 months)'
  /buycott 'Buycotted (last 12 months)'
  /runwalk 'Ran/walked/biked for charity (last 12 months)'
  /raisemon 'Raised money for charity (last 12 months)'
  /canvass 'Canvassed (last 12 months)'
  /voting 'Regular voting'.

value labels contoff,contmed,talkshow,protest,epet,wpet,buycott,boycott,canvass 0 'No' 1 'Yes'.
compute raisemoo=0.
if raisemon=1 or runwalk=1 raisemoo=1.
var labels raisemoo 'Raised money for charity or ran/walked (last 12 months)'.