*master national syntax file for National Civic Engagement Survey I, Spring 2002.

GET FILE='C:\Civic Engagement Spring 2002.sav'.
weight by step2wt.

********shorter variable labels***********.
variable labels
int3 "int3: diff in cmty"
int4 "INT4: WORK INFORMALLY"
PR1 "PR1:POLLUTION"
PR2 "PR2: TAXES"
PR3 "PR3: DISCRIMINATION"
PR4 "PR4: ABORTION"
PR5 "PR5: HEALTH INS"
PR6 "PR6: SOC SEC"
PR7 "PR7: EDUC"
VP1 "VP1: REG"
VP2 "VP2: VOTED"
VP3 "VP3: VOTE FREQ"
VP3A "VP3A: FUTURE VOTE"
PP1 "PP1:PERSUADE"
PP2 "PP2: BUTTON"
PP5 "PP5: CONTACTED?"
PP6 "PP6: CONTRIBUTE"
ATA1 "ATA1: HELPFUL"
ATA2 "ATA2: GUIDELINES"
ATA3 "ATA3: RESP FOR SOCIETY"
ATA4 "ATA4: FREE SPEECH"
ATA6 "ATA6: GOVT DO MORE"
ATA7 "ATA7: POLS POWER"
ATA8 "ATA8: CONFLICT"
ATA9 "ATA9: CITIZEN"
ATA10 "ATA10: GOVT CONTROL"
ATA11 "ATA11: GOVT RESPONSIVE"
ATA12 "ATA12: GROUP EFFICACY"
MI1 "MI1: FOLLOW"
MI1A "MI1A: WHY NOT FOLLOW?"
MI2 "MI2:TALK NEWS"
MI3 "MI3:TALK POLS"
MI4 "MI4:POLS TALKED HOME"
MI4A "MI4A: POLS TALK HOME"
MI5 "MI5:ANYONE VOL"
MI5A "MI5A:ANYONE ELSE VOL"
MI6 "MI6:SOC NETWORK"
MI7A "MI7A:NEWSPAPER"
MI7B "MI7B:NEWS MAGS"
MI7C "MI7C:TV NEWS"
MI7D "MI7D:RADIO"
MI7E "MI7E:NET NEWS"
MI8 "MI8:TV HOURS"
PP7A "PP7A:CONTACT"
PP7B "PP7B:LETTER"
PP7C "PP7C:TALK RADIO"
PP7D "PP7D: PROTEST"
PP7E "PP7E:EMAIL PETITION"
PP7F "PP7F: WRITTEN PETITION"
PP7G "PP7G:BOYCOTT"
PP7H "PP7H:BUYCOTT"
PP7I "PP7I:BIKE"
PP7J "PP7J:CHARITY"
PP7K "PP7K:CANVASS"
ATB1 "ATB1:TAKE ADV"
ATB2 "ATB2:DUTY"
ATB3 "ATB3:REG BUS"
ATB4 "ATB4:EQ OPP"
ATB5 "ATB5:GAYS"
ATB6 "ATB6:IMMIGRANTS"
ATB7 "ATB7:GEN ID"
ATB8 "GOVT WASTE"
S1 "S1:HS CLUBS"
S2 "S2: HS CLUBS #"
S3 "S3: POL CLUBS"
S1A "S1A:HS CLUBS"
S2A "S2A: HS CLUBS #"
S3A "S3A: POL CLUBS"
S4 "S4:CLASS REQS"
S5 "S5:CLASS DISC"
S6 "S6:MAKE UP MIND"
K1 "KI:SOC SEC"
K2 "K2:GOP CONS"
K4 "K4:VETO"
V1 "V1:VOLUNTEER"
V2A "V2A:VOL REL"
V2B "V2B:VOL POL"
V2C "V2C:VOL ENV"
V2D "V2D:VOL CIV"
V2E "V2E:VOL KID"
V2F "V2F:VOL OTHER"
V3RELIG "V3:VOL FREQ"
V4RELIG "V4:WHEN LAST VOL"
V5RELIG "V5:WHY VOL"
V6RELIG "V6:VOL CONTACT"
V8 "V8:VOL HELP"
V9a_1 "V9:WHO HELP?".

missing values dage (5,9).


************************************VARIABLES BELOW (THROUGH THE TYPOLOGY) HAVE BEEN*****.
***********************************COMPUTED AND ARE IN THE SYSTEM FILE*****************************.

****************************creating group membership variables that work with either form *****************.
do if not sysmis(gp1).
compute anygroup=0.
if any (1,gp1 to gp9) anygroup=1.
end if.

do if not sysmis(gpa).
recode gpa (1=1)(else=0) into anygroup.
end if.

compute expform=0.
if sysmis(gp1) expform=1.
value labels expform 0 'Long version of group' 1 'Short version'.

recode gxa (1,4=1)(else=0) into active.
recode gxb (1=1)(else=0) into polgroup.
var labels active 'Active member of at least one group'
  /polgroup 'Member of group involved in politics'.


************************************PARTICIPATION SCALE - DICHOTOMOUS MEASURES***************************************************

recode v1 (1=1)(else=0) into volunt.
var labels volunt 'volunteered in last 12 months (any type)'.
compute voting=0.
do if not sysmis(vp3).
if vp3 =1 voting=1.
end if.
do if not sysmis(vp3a).
if vp3a=1 voting=1.
end if.
var labels voting 'Regular voting'.
recode int4 (1=1)(else=0) into commprob.
recode pp1 (1=1)(else=0) into persuade.
recode pp2 (1=1)(else=0) into button.
recode pp6 (1=1)(else=0) into money.
recode pp7a (3=1)(else=0) into contoff.
recode pp7b (3=1)(else=0) into contmed.
recode pp7c (3=1)(else=0) into talkshow.
recode pp7d (3=1)(else=0) into protest.
recode pp7e (3=1)(else=0) into epet.
recode pp7f (3=1)(else=0) into wpet.
recode pp7g (3=1)(else=0) into boycott.
recode pp7h (3=1)(else=0) into buycott.
recode pp7i (3=1)(else=0) into runwalk.
recode pp7j (3=1)(else=0) into raisemon.
recode pp7k (3=1)(else=0) into canvass.
execute.

var labels contoff 'Contacted official'
  /commprob 'Worked to solve community problem'
  /persuade 'Tried to persuade others in election'
  /button 'Displayed campaign button or sign'
  /money 'Donated money to candidate or party'
  /contmed 'Contacted news media'
  /talkshow 'Called a talk show'
  /protest 'Protested'
  /epet 'Signed e-mail petition'
  /wpet 'Signed paper petition'
  /boycott 'Boycotted'
  /buycott 'Buycotted'
  /runwalk 'Ran/walked/biked for charity'
  /raisemon 'Raised money for charity'
  /canvass 'Canvassed'.
value labels contoff,contmed,talkshow,protest,epet,wpet,buycott,boycott,canvass 0 'No' 1 'Yes'.
compute raisemoo=0.
if raisemon=1 or runwalk=1 raisemoo=1.
var labels raisemoo 'Raised money for charity or ran/walked'.

*********creating principal measure of regular volunteer activity*******************.
count npvolrgn=v3RELIG,v3ENVIR,v3CIVIC,v3YOUTH,v3OTHER (1).
var labels npvolrgn 'number of nonpol groups vol regularly for'.
recode npvolrgn (0=0)(else=1) into npvolreg.
var labels npvolreg 'regular volunteer for nonpolitical organization'.

compute vpolreg=0.
if v3POLIT=1 vpolreg=1.
var labels vpolreg 'vol regularly for cand or pol group'.

****volunteering for political group -- not regularly ****************.
compute polvol=0.
if v2b=1 polvol=1.
var labels polvol 'volunteered for cand or pol group'.


****************************creation of typology of engaged citizen*****************************************.
compute civideal=sum(npvolreg,commprob,active,raisemoo).
var labels civideal 'Four item civic engagement index for ideal citizen'.
compute polideal=sum(button, money, persuade,polvol, voting).
var labels polideal 'Five item political engagement index'.
value labels polideal civideal 0 '0' 1 '1' 2 '2' 3 '3' 4 '4' 5 '5'.
compute voiideal=sum(contoff,contmed,talkshow,protest,epet,wpet,buycott,boycott,canvass).
var labels voiideal 'Nine item voice engagement index'.
recode polideal (0,1=0)(2,3,4,5=1) into polid2.
recode civideal (0,1=0)(2,3,4=1) into civid2.
var labels polid2 'Score on electoral ideal index'.
var labels civid2 'Score on civic ideal index'.
value labels polid2 civid2  0 'Less than 2' 1 '2 or higher'.
recode voiideal (0,1,2=0)(else=1) into voiid2.
var labels voiid2 'score of voice ideal index'.
recode voiideal (0,1=0)(else=1) into voiidx.
var labels voiidx 'voice ideal index 0,1=0'.
var labels voiid2 'score of voice ideal index'.


*** computing typology *****.
compute typolid1=0.
if polid2=1 and civid2=0 typolid1=1.
if polid2=0 and civid2=1 typolid1=2.
if polid2=1 and civid2=1 typolid1=3.
var labels typolid1 'Typology of Engagement'.
value labels typolid1 0 'Disengaged' 1 'Electoral specialist' 2 'Civic specialist' 3 'Dual activist'.


*******************************creating media variables for inclusion in engagement scales********************************.
recode mi7a (8,9=0)(else=copy) into newsp.
recode mi7b (8,9=0)(else=copy) into newsmag.
recode mi7c (8,9=0)(else=copy) into tvnews.
recode mi7d (8,9=0)(else=copy) into radionew.
recode mi7e (8,9=0)(else=copy) into netnews.

compute mediause=sum(newsp,newsmag,tvnews,radionew,netnews).